<cfcomponent output="false">
	<cfscript>
		this.name = "errorHandling";
	</cfscript>
	
	...

	<cffunction name="onRequestStart" returnType="boolean" output="true">
		<cfargument name="targetPage" type="String" required="true" />	
		
		<!--- 3rd layer error handling [last and final being the CFADMIN settings] --->
		<cferror type="exception" template="errorTemplates\exception.cfm" exception="any">
		<cferror type="request" template="errorTemplates\request.cfm" exception="any">
		<cferror type="validation" template="errorTemplates\validation.cfm" exception="any">

		<cfreturn true />
	</cffunction>

	...

	<!--- handle 404 errors --->
	<cffunction name="onMissingTemplate" returnType="boolean" output="true">
		<cfargument name="targetpage" type="String" required="true" />
		
		<cfset var retval = true />
		
		<cftry>
		    <cfheader statusCode="404" statusText="Page Not Found" />

		    <cfinclude template="errorTemplates\missingInclude.cfm">
		   
		    <!--- return true prevents the default ColdFusion error handler from running --->
		    <cfset retval = true />
	    <cfcatch type="any">
	    	<!--- 	return false will allow ColdFusion's default error handler to run and 
	    			this will force the CFADMIN to display the missing template file (if present) --->
	        <cfset retval = false />
	    </cfcatch>
		</cftry>

		<cfreturn retval />
	</cffunction>

	<!--- 	handle script/500 errors
			2nd layer error handling [1st being CFTRY/CFCATCH] --->
	<cffunction name="onError" returnType="void" output="true">
		<cfargument name="exception" required="true" />
		<cfargument name="eventname" type="String" required="true" />

		<cfsavecontent variable="errorData">
			<cfoutput>
			  EventName: #arguments.eventName# 
			| Detail: #arguments.exception.detail# 
			| Message: #arguments.exception.message# 
			| StackTrace: #arguments.exception.stackTrace# 
			| Type: #arguments.exception.type# 
			| name: #arguments.exception.name# 
			| template: #arguments.exception.tagContext[1].template# 
			| line: #arguments.exception.tagContext[1].line# 
			| rawtrace: #arguments.exception.tagContext[1].raw_trace# 
			</cfoutput>
		</cfsavecontent>

		<cflog type="error" application="true" file="onErrorData" text="#errorData#" />
		
		<cfinclude template="errorTemplates\onError.cfm">
		
		<!--- 	throw an error to allow ColdFusion's default error handler to run and 
	    		this will force the CFADMIN to display the site wide error template file (if present)
	    
	    <cfthrow message="#errorData#" /> --->
		
		<cfreturn />
	</cffunction>
</cfcomponent>